BasicView Overview / Demo

I figured it was about time I go over the BasicView (a very simple implementation of setting up your viewport/scene/camera all in one object). The thing that is amazing to me is that you can implement and display a 3D object in 34 lines of code using BasicView.

In this example we're going to simply display a Plane primitive (so don't expect to see any amazing visuals). Lets jump into the code and see how it breaks down.

package {
import flash.display.Sprite;
import flash.events.Event;

//for BasicView you will need to import CameraType instead of a specific camera
import org.papervision3d.cameras.CameraType;
import org.papervision3d.materials.ColorMaterial;
import org.papervision3d.objects.primitives.Plane;
import org.papervision3d.render.BasicRenderEngine;

//import the BasicView class
import org.papervision3d.view.BasicView;

public class BasicViewDemo extends Sprite
{

//Declare your BasicView variable
private var view:BasicView;
private var color:ColorMaterial;
private var plane:Plane;

public function BasicViewDemo()
{

//The BasicView parameters are as follows
//BasicView(width, height, scaleToStage, interactive, camera type);
view = new BasicView(600, 400, false, false, CameraType.FREE);
//When you instantiate the camera type
//there are three type, DEBUG, FREE, TARGET.

plane = new Plane(new ColorMaterial(0x880000), 300, 300, 1, 1);

//assign the BasicView renderer property to a renderer of your choice.
//for this example I'll assign it to a BasicRenderEngine renderer.
view.renderer = new BasicRenderEngine();

//any objects that you want to add to your scene
//needs to be added through view.scene
view.scene.addChild(plane);

addEventListener(Event.ENTER_FRAME, onRenderViewport);

//add the BasicView object to the display list
addChild(view);
}

private function onRenderViewport(e:Event):void
{

//to render your scene use the view.singleRender(); method
view.singleRender();

}
}
}

View Example: click here
View Source: click here